Física Teórica 3 - Segundo cuatrimestre de 2014
Problema 2 de la Guía 7.

Una comparación entre las funciones PolyLog, que son las funciones (Subscript[g, ν]), y la función Log[2/(2-x)] que aparece en el problema.

(*Todas las celdas que tienen el fondo de este mismo color son ejecutables - con shift+enter o el enter del teclado numérico*)

Plot[{PolyLog[5/2, x], PolyLog[3/2, x],Log[(2/(2-x))]}, {x, 0, 1}, PlotStyle-> {Thin, Thin, Thick}, PlotLabel-> Style["(Subscript[g, 5/2])[x],   (Subscript[g, 3/2])[x],   Log[(2/(2 - x))]", 20], Background->LightGray]

La función Log[2/(2-x)] tiene las características cualitativas de una (Subscript[g, v]) para ν>1.Converge en z = 1 y todas sus derivadas son mayores que cero en el intervalo 0, 1.

Las funciones termodinámicas intensivas y n.

p = presión
u = energía por partícula
p0 = presión de las partículas en el nivel fundamental
v = volumen por partícula
T = temperatura
n = número de partículas
(constante de Bolztman = 1)

p[z_, T_, n_, v_]:= -(T/(n v))Log[1-z] +2 (T^(5/2))Log[(2/(2-z))];
u[z_, T_,  v_]:= 3 v (T^(5/2)) Log[(2/(2-z))] ;
p0[z_,T_,  n_, v_]:=  -(T/(n v))Log[1-z];

La ecuación que satisface la fugacidad.

ec[z_, T_, n_, v_]:=(n ==  (z/(1-z)) +n  v (T^(3/2))  ((2z)/(2-z)));

La solución, en términos de un parámetro a = v (T^(3/2)).

sol = Solve[ec[z, T, n, (a/(T^(3/2)))], z]

Cada solución de la cuadrática por separado, para investigar cuál corresponde al caso físico con 0 < z < 1.

sol1[n_, a_]:= ((-2-3 n-2 a n+(Sqrt[4+4 n+8 a n+(n^2)-4 a (n^2)+4 (a^2) (n^2)]))/(2 (-1-n-2 a n)));
sol2[n_, a_]:=((2+3 n+2 a n+(Sqrt[4+4 n+8 a n+(n^2)-4 a (n^2)+4 (a^2) (n^2)]))/(2 (1+n+2 a n)));

Las dos soluciones graficadas como función del parámetro a = v (T^(3/2)), permitiendo variar n, en este caso escrito como n = (10^x).

Manipulate[Plot[{sol1[(10^x), a], sol2[(10^x), a]}, {a, 0, 3},PlotStyle-> {Blue, Red}, PlotLabel-> Style["Las dos soluciones para z", 20], Background->LightGray, AxesLabel-> {Style["\!\(TraditionalForm\`\(\(\\ \)\(v\\ \*SuperscriptBox[\(T\), \(3/2\)]\)\)\)", 20], None}], {{x, 2}, 0,4, Appearance-> "Open"}]

La solución física es la función antes llamada sol1. Notar cómo la solución tiende a 1 de manera abrupta por debajo del valor crítico  (Subscript[a, crit]) = 1/2. Cuanto mayor es n, más marcada es la transición.

zeta[n_, a_]:= sol1[n, a];

La fracción de partículas en el nivel fundamental como función de la temperatura para v = 1.

La barra del gráfico de abajo permite variar el número de partículas, escrito aquí como (10^x).

n0[z_, n_]:=(1/n) (z/(1-z));

Manipulate[Plot[{n0[zeta[(10^x), (T^(3/2))], (10^x)]}, {T, 0,2}, PlotRange-> {0, 1}, PlotLabel-> Style["(Subscript[n, 0])", 20], Background->LightGray, AxesLabel-> {Style["T", 20], None}], {{x, 2}, 0, 6, Appearance-> "Open"}]

Dado que el valor crítico de a = v (T^(3/2)) es 1/2, el valor crítico de la temperatura para v = 1 es T = 1/(2^(2/3))= 0.6299... Notar lo que ocurre con n0 al aumentar n.

La presión de las partículas en el nivel fundamental, p0[z, T,  n, v].

Se grafica (Subscript[p, 0]) v para  T = 1. En tal caso la variable independiente es el parámetro a = v. Por comodidad, el número de partículas está escrito como (10^n).

Manipulate[Plot[{a p0[zeta[(10^n), a],1,  (10^n), a]}, {a, 0, 3}, PlotRange-> All, PlotLabel-> Style["(Subscript[p, 0])v", 20], Background->LightGray,AxesLabel-> {Style["v", 20], None}], {{n,2}, 0, 6,  Appearance-> "Open"}]

Notar como al aumentar n el valor máximo de la presión de las partículas en el nivel fundamental decrece fuertemente. (Prestar antención a la escala vertical.) Además, notar que se está graficando (Subscript[p, 0])v. Ustedes pueden graficar (Subscript[p, 0]) por separado. Les va a convenir usar escala logarítmica.

La presión total p[z, T, v, n]

Se grafica p v para  T = 1. En tal caso, la variable independiente es el parámetro a = v. El valor crítico del volumen por partícula es 1/2. Por comparación también se muestra la presión del fundamental.

Manipulate[Plot[{a p[zeta[(10^n), a],1,  (10^n), a],a p0[zeta[(10^n), a],1,  (10^n), a]}, {a, 0.01, 3}, PlotRange-> All, PlotLabel-> Style["(Subscript[vp, total])  vs   (Subscript[vp, 0])", 20], Background->LightGray,AxesLabel-> {Style["v", 20], None}], {{n, 1.}, 0, 6, Appearance-> "Open"}]

Notar que a medida que aumenta n, el cambio en la derivada de la presión cerca del valor crítico del volumen se hace cada vez más abrupto. Abajo se grafica la derivada de p v respecto de v.

derivada[n_, a_]:= Evaluate[D[a p[zeta[(10^n), a],1,  (10^n), a],a]]

Manipulate[Plot[derivada[n, a], {a, 0, 3}, PlotRange-> All,  PlotLabel-> Style["((dpv )/dv)", 20], Background->LightGray,AxesLabel-> {Style["v", 20], None}], {{n, 2}, 0, 6,  Appearance-> "Open"}]

Esto está relacionado con la compresibilidad. No es directamente el inverso de la compresibilidad porque se calcula la derivada de p v respecto de v. Piensen que en el caso de un gas ideal clásico, eso da cero, y es lo que se ve en el gráfico de arriba para valores grandes de v donde todas las cosas tienden a ser clásicas.

La energía por partícula u[z, T, v].

Se grafica como función de la temperatura para v = 1. La barra permite variar el número de partículas, definido como (10^n)

Manipulate[Plot[{ u[zeta[(10^n), a],(a^(2/3)),  1]}, {a, 0, .8}, PlotRange-> All,PlotLabel-> Style["energía/partícula", 20], Background->LightGray,AxesLabel-> {Style["T", 20], None}], {{n, 2}, 0, 8,  Appearance-> "Open"}]

Notar que al aumentar n, el cambio en la derivada de u respecto de la temperatura se hace cada vez más marcado. Esa derivada es el calor específico, que en el límite en que n-> ∞ tiene una discontinuidad.

El calor específico

El gráfico muestra el calor específico como función de T para v = 1.

cv[n_, T_, v_]:= Evaluate[D[u[zeta[n, v (T^(3/2))],  T, v], T]];

Manipulate[Plot[{ cv[(10^n),T,  1]}, {T, 0, 1.5}, PlotRange-> All,PlotLabel-> Style["calor específico", 20], Background->LightGray,AxesLabel-> {Style["T", 20], None}], {{n, 2}, 0, 8, Appearance-> "Open"}]

Notar como va apareciendo la discontiuidad en el valor crítico de la temperatura a medida que aumenta el número de partículas.