Quit[]

Definimos el potencial exacto. Para esto seteamos λ=1, o sea, el potencial se mide en unidades de λ. Fijamos también a=1, o sea, las longitudes se miden en unidades de la separación entre los planos

ϕ[x_,y_]:=Log[((1+2 (E^(-π Abs[y]))Sin[π x]+(E^(-2 π Abs[y])))/(1-2 (E^(-π Abs[y]))Sin[π x]+(E^(-2 π Abs[y]))))]

Definimos a su vez el potencial aproximado, como una suma parcial hasta el valor “n” a partir del resultado que obtuvimos con la primer separación de variables.

ϕn[x_,y_,n_]:=4 Sum[((((-1))^l)/(2l+1))Sin[(2l+1)π x](E^(-(2l+1)π Abs[y])),{l,0,n}]

En tercer  lugar definimos el potencial aproximado como una integral numérica a partir del resultado que obtuvimos con la segunda separación de variables. Notemos que definimos el potencial de a pedazos (así fue nuestro resultado)

ϕI[x_,y_]:=Piecewise[{{NIntegrate[(1/k)(E^(I k y))((Sinh[k x])/(Cosh[k /2])),{k,-∞,∞}],0≤x<1/2},{NIntegrate[(1/k)(E^(I k y))((Sinh[k (1-x)])/(Cosh[k /2])),{k,-∞,∞}],1/2≤x≤1}}] //Chop

Aquí graficamos el perfil del potencial con x corriendo entre 0 y 1 (entre una pared y la otra) y variando “y” con y=0.1, 0.3, 0.4, 1, 2. Vemos que el potencial va de 0 a 0 entre las paredes (como corresponde a la condición de contorno que impusimos) y es máximo en el centro. A su vez, el máximo es más alto cuanto más cerca del hilo estemos (y->0)

Plot[{ϕ[x,0.1],ϕ[x,0.3],ϕ[x,0.4],ϕ[x,1],ϕ[x,2]},{x,0,1}]

Si nos paramos en y=0 y nos movemos en x, encontramos una divergencia en x=1/2, que es donde está el hilo cargado:

Plot[ϕ[x,0],{x,0.4,0.6}]

Pasemos a estudiar el error de la expresión de la transformada de Fourier numérica. Nos paramos en valores de y fijos (y=0, 0.5, 1, 2) y variamos x entre 0 y 1. Vemos que a lo sumo cometemos un error de 10^(-9). Observar que cuando x=1/2 e y=0 obtenemos ∞ pero esto es esperable pues el potencial explota allí en presencia del hilo infinito como vimos en el gráfico anterior

Table[ϕ[x,0]-ϕI[x,0],{x,0.1,0.9,0.1}]//Quiet

Table[ϕ[x,0.5]-ϕI[x,0.5],{x,0.1,0.9,0.1}]//Quiet

Table[ϕ[x,1]-ϕI[x,1],{x,0.1,0.9,0.1}]

Table[ϕ[x,2]-ϕI[x,2],{x,0.1,0.9,0.1}]

Ahora queremos estudiar cuán rápido converge la serie parcial de Fourier variando el número de términos que incluímos en la suma “n” (la última entrada de ϕn[x,y,n]). Si tomamos un valor fijo de y lejos del centro, digamos y=1, y=2, y nos movemos en x vemos que todos los gráficos se solapan. Es decir, lejos del hilo, alcanza con 1 o 2 términos en la serie para tener mucha precisión

Plot[{ϕ[x,2],ϕn[x,2,0],ϕn[x,2,1],ϕn[x,2,2],ϕn[x,2,3],ϕn[x,2,4]},{x,0,1}]

Plot[{ϕ[x,1],ϕn[x,1,0],ϕn[x,1,1],ϕn[x,1,2],ϕn[x,1,3],ϕn[x,1,4]},{x,0,1}]

En cambio, si hacemos lo mismo para un valor de y cercano al hilo, por ejemplo y=0.1, vemos que necesitamos varios términos de la serie para obtener una aproximación aceptable.

Plot[{ϕ[x,0.1],ϕn[x,0.1,0],ϕn[x,0.1,1],ϕn[x,0.1,2],ϕn[x,0.1,3],ϕn[x,0.1,4]},{x,0,1}]

Por último graficamos el perfil de la densidad superficial de carga de las paredes a tierra. Como se ve en el gráfico, casi toda la carga está concentrada en el centro, cerca de y=0 (y extendida uniformemente a lo largo de z)

Plot3D[-(1/2)(1/(Cosh[π y])),{y,-2,2},{z,-2,2}]